cara menjumlahkan di excel
Image by Wilfried Pohnke from Pixabay

Operasi Penjumlahan memang sudah sangat akrab dengan kehidupan kita sehari-hari. Kegiatan menjumlahkan sesuatu yang pada awalnya dikerjakan oleh manusia dengan menggunakan kemampuan otak, menghitung jari tangan, dibantu alat hitung sederhana semacam sempoa, hingga sampailah pada saat ini mampu dikerjakan dengan cepat berbekal mesin kalkulator dari hp di genggaman tangan yang cuma ditekan-tekan saja. 

Tidak ketinggalan teknologi gawai lainnya, salah satu diantaranya adalah perangkat komputer PC atau Laptop yang menjadi andalan utama bagi setiap penggunanya dalam memecahkan setiap masalah perhitungan dengan mudah. Excel hadir sebagai software spreadsheet komputer untuk menangani bermacam-macam perhitungan yang layak untuk anda kuasai. 

Kali ini kami membagikan beberapa tips menjumlahkan di Excel yang dapat diikuti oleh siapa saja bagi yang bersemangat ingin belajar Excel terutama bagi pemula. Kami akan menuntun Anda setahap demi setahap dalam menguasai teknik menjumlahkan suatu perhitungan melalui Excel.

Silakan baca postingan Cara Menjumlahkan Barisan Sel Bilangan Pada Tiap Kolom Menggunakan Macro VBA Excel untuk mempelajari cara menjumlahkan di Excel dengan VB.

Daftar Isi



Cara Menjumlahkan di Excel dengan menu AutoSum

Menu AutoSum dalam Excel adalah sebuah tombol perintah yang paling banyak dikenali dan sering digunakan oleh banyak pengguna Excel. Ada dua tempat menu AutoSum ini di menu ribbon yang dapat diakses yaitu melalui:
  1. Tab Home > Editing.
  2. Tab Formulas > Function Library.

Cara Menggunakan AutoSum di Excel

Dalam Excel terdapat fungsi SUM, gunanya untuk menjumlahkan semua bilangan yang ada di suatu barisan sel atau range yang disorot. Fungsi SUM ini sering digunakan dalam rumus Excel penjumlahan ke bawah (menurun/vertikal) maupun rumus Excel penjumlahan ke samping (mendatar/horizontal). 

Adapun fungsi SUM ini digunakan secara manual dengan cara mengetikkan fungsi ke dalam formula, Namun demikian, fungsi SUM ini dapat pula dilakukan secara otomatis yaitu dengan menggunakan menu AutoSum. Untuk menghasilkan rumus SUM secara otomatis pada suatu sel:
  1. Langkah pertama, kita hanya menempatkan sel mana yang akan menjadi output SUM.
  2. Lalu melalui salah satu dari kedua tab (tempat di menu ribbon seperti dijelaskan di atas), klik tombol AutoSum. Kemudian Excel otomatis menganalisis data di sekitar sel output dan menyorot barisan sel yang akan dijumlahkan dengan rumus SUM.
  3. Selanjutnya anda melakukan konfirmasi. Jika barisan sel yang disorot tersebut tidak tepat, maka tekan Esc untuk membatalkan perintah atau Anda memperbaiki hasil sorotan Excel dengan menyorot barisan sel yang menurut Anda tepat. Namun jika barisan sel yang akan dijumlahkan tersebut telah disorot otomatis dengan tepat maka Anda klik lagi tombol AutoSum atau tekan Enter untuk menampilkan hasil penjumlahan.
Cara terbaik untuk memulai belajar Excel adalah dengan praktek melalui contoh worksheet sederhana dari file latihan-autosum-bukuyudi.xlsx yang bisa diunduh disini. Silakan Anda coba praktekkan langkah-langkah di atas pada Sheet1 tepatnya di sel C13. 

Di bawah ini kami sajikan beberapa tips seputar tombol AutoSum yang dapat anda coba praktekkan. 

Cara Cepat Menjumlahkan Bilangan dengan Keyboard

Tombol keyboard jika Anda mengetahui dan menggunakannya, maka pasti dapat membuat Anda menjadi semakin terlihat mahir dan jago dalam menguasai Excel. Untuk menjumlahkan bilangan dengan cepat dan singkat yaitu dengan cara menekan tombol:
Alt + = 
yang fungsinya sama persis dengan tombol AutoSum.

Anda bisa membuka Sheet1 pada file latihan-autosum-bukuyudi.xlsx dan mencoba menerapkan cara ini pada sel C13. Pastikan sel C13 dikosongkan dulu (di Delete) sebelum memulai.

Cara Menjumlahkan melalui Menu Pilihan Menurun pada Tombol AutoSum

Jika anda perhatikan pada tombol AutoSum terdapat segitiga kecil terbalik atau mata panah menurun ke bawah, ketika Anda klik, tombol AutoSum menampilkan daftar menu menurun, terdiri dari fungsi berikut:
  • Sum: menghasilkan fungsi SUM untuk menjumlahkan bilangan.
  • Average: fungsi AVERAGE untuk menghasilkan rata-rata bilangan.
  • Count Numbers: fungsi COUNT untuk menghitung bilangan yang ada pada barisan sel tersorot. Fungsi ini banyak digunakan sebagai rumus excel menghitung jumlah data.
  • Max: fungsi MAX menampilkan nilai yang paling besar pada barisan sel yang dipilih.
  • Min: fungsi MIN menampilkan nilai paling kecil pada barisan sel yang dipilih.
  • More Functions...: menampilkan kotak dialog Insert Function yang bisa juga diakses melalui tombol fx di ujung sebelah kiri formula bar atau melalui tab Formulas > Function Library > Insert Function.
Melalui menu inilah Anda dapat memilih output hasil penjumlahan menggunakan fungsi selain SUM.

Cara Cepat Menjumlahkan Bilangan Pada Suatu Range

Anda bisa menyorot terlebih dahulu barisan sel manakah yang akan dijumlahkan sebelum Anda meng-klik tombol AutoSum, sehingga Excel akan langsung memberikan hasil penjumlahan tanpa harus menunggu konfirmasi Anda lagi. 

Pada Sheet1 file latihan-autosum-bukuyudi.xlsx, terlebih dahulu pastikan agar sel C13 kosong, lalu Anda sorot sel C4 hingga C12 kemudian jalankan perintah AutoSum mana saja yang anda sukai.

Cara Cepat Menjumlahkan Tabel Bilangan dengan Hasil Penjumlahan Berada di Kanan dan Bawah Tabel

Untuk menjumlahkan suatu tabel bilangan dengan cepat.
  1. Anda sorot range bilangan ditambah dengan satu kolom tambahan ke kanan dan satu baris tambahannya ke bawah.
  2. Klik tombol AutoSum dan Excel otomatis memberikan anda seluruh hasil penjumlahan dengan cepat.
Silakan Anda buka tab Sheet3 di file latihan-autosum-bukuyudi.xlsx, sorot sel B3 hingga ke G9 lalu jalankan perintah AutoSum yang mana saja.

Untuk lebih lanjut mempelajari tabel Excel, silakan simak postingan Cara Membuat Database dengan Excel disertai Form Entri Data.

Fakta Unik Seputar AutoSum di Excel

Menu perintah AutoSum ini terkadang menghasilkan output yang tidak terduga dan jarang sekali kita pikirkan bila digunakan pada kasus tertentu seperti di bawah ini. Jika Anda menemukan nilai atau output unik yang dihasilkan menu AutoSum ini, silakan berbagi pengalaman Anda dengan cara berkomentar di bawah.  
 

Fakta AutoSum #1 

Fakta yang pertama adalah jika pada suatu barisan sel bilangan hanya ada beberapa sel tersorot saja yang akan dijumlahkan, maka Excel akan menghasilkan outputnya pada sel kosong di paling akhir dari deretan bilangan yang terdapat pada barisan sel tersebut. 

Silakan buka tab Sheet1 pada file latihan-autosum-bukuyudi.xlsx, terlebih dahulu pastikan sel C13 kosong, lalu coba Anda sorot C4 sampai C7, jalankan perintah AutoSum favorit Anda. 

Fakta AutoSum #2 

Fakta menarik yang kedua adalah ketika Anda membuat suatu data tabel Excel yang dihasilkan melalui Insert > Tables > Table, coba anda jumlahkan data pada tabel menggunakan AutoSum. Ternyata nilai yang dihasilkan tersebut memang benar merupakan hasil penjumlahan yang tepat namun fungsi yang digunakan pada rumusnya bukanlah fungsi SUM yang seharusnya, melainkan fungsi SUBTOTAL.

Buka Sheet4 latihan-autosum-bukuyudi.xlsx, coba anda letakkan pointer di sel C9, lalu jalankan perintah AutoSum, setelah itu perhatikan fungsi yang terdapat pada formula bar.

Fakta AutoSum #3 

Fakta terakhir mengenai fungsi AutoSum ini adalah meskipun format bilangan barisan sel yang akan dijumlahkan berbeda-beda (misalnya ada yang format bilangannya persen, pecahan, mata uang, dan sebagainya), maka perintah AutoSum akan tetap menghasilkan nilai penjumlahannya dengan tampilan format bilangan sama persis seperti sel pertama barisan sel yang dijumlahkan tersebut. 

Anda buka Sheet2 file latihan-autosum-bukuyudi.xlsx, pada kolom C terdapat beberapa bilangan dengan format yang telah dibedakan, silakan Anda buktikan fakta ini sendiri dengan menjalankan perintah AutoSum pada sel C13. Apakah format bilangan mengikuti sel pertama yang disorot (tepatnya sel C4)?

Itulah pembahasan tentang cara menjumlahkan otomatis di Excel dengan menu AutoSum. Selanjutnya Anda akan mempelajari cara menjumlahkan melalui rumus Excel.

Rumus Excel Menjumlahkan Menggunakan Fungsi SUM

Silakan Anda terlebih dahulu mengunduh file latihan-sum-bukuyudi.xlsx disini agar materi ini lebih mudah untuk diikuti dan dipahami dengan baik.

Rumus SUM Excel Menjumlahkan Data di Suatu Range

Contoh-contoh sheet pada file latihan-sum-bukuyudi.xlsx akan menunjukkan cara penjumlahan biasa dengan menggunakan formula SUM.

Rumus SUM Excel Menjumlahkan Barisan Sel yang Telah Diberi Nama

Silakan buka Sheet1 pada file latihan-sum-bukuyudi.xlsx yang telah Anda unduh kemudian Anda ikuti langkah-langkah berikut:
  1. Sorot sel B2 hingga ke sel B8.
  2. Klik Name Box (kotak isian di ujung kiri atas sejajar formula bar).
  3. Beri nama barisan sel misalnya 'DataJan'.
  4. Tekan Enter.
  5. Letakkan pointer di sel B9.
  6. Ketik =SUM lalu tekan tombol Tab pada keyboard.
  7. Ketik huruf D lalu akan muncul daftar pilihan menurun, inilah yang disebut dengan menu autocomplete.
  8. Dalam autocomplete tersebut terdapat DataJan selanjutnya Anda tekan tombol Tab.
  9. Tekan Enter.
Penulisan rumus seperti ini:
=SUM(DataJan)
Sangat mudah bukan? Rumus ini menghasilkan penjumlahan semua nilai yang ada di dalam barisan sel bernama DataJan.

Rumus SUM Excel Menjumlahkan Data pada Kolom yang Saling Berjauhan 

Kasus berikutnya adalah menjumlahkan kolom yang banyak dan terpisah oleh kolom lain di sampingnya sehingga kolomnya berjauhan atau kolom yang akan dijumlahkan tersebut selang-seling.

Anda bisa coba praktekkan di Sheet2, sel B12 harus menghasilkan jumlah total bulan Jan+Mar+Mei. Adapun caranya sebagai berikut:
  1. Letakkan pointer di sel B12.
  2. Ketik =SUM lalu tekan Tab.
  3. Sorot sel B2 hingga ke sel B10.
  4. Lalu tekan koma (,)*.
  5. Sorot sel D2 hingga ke sel D10.
  6. Lalu tekan koma (,)*.
  7. Sorot sel F2 hingga ke sel F10.
  8. Tekan Enter.
Penulisan rumusnya:
=SUM(B2:B10,D2:D10,F2:F10)
Silakan Anda berlatih menghasilkan nilai pada sel B14 dengan cara seperti yang telah dijelaskan di atas.

*atau titik koma (;) bagi pengguna dengan pengaturan sistem bahasa Indonesia


Rumus SUM Excel Menjumlahkan Data di Sepanjang Kolom Worksheet

Pada situasi tertentu, Anda jangan ragu untuk menjumlahkan seluruh data yang ada di sepanjang kolom, Contohnya kolom B pada Sheet3 latihan-sum-bukuyudi.xlsx, caranya sebagai berikut:
  1. Letakkan pointer di sel A1.
  2. Ketik =SUM lalu tekan Tab.
  3. Klik tombol Heading B di bawah formula bar maka Excel menyorot sepanjang kolom yang ada di Sheet3.
  4. Tekan Enter.
Rumusnya:
=SUM(B:B)

Rumus SUM Excel Menjumlahkan Seluruh Data yang Ada di Worksheet Lain

Buka Sheet4 file latihan-sum-bukuyudi.xlsx lalu letakkan pointer di area worksheet pada sel mana saja dan ketikkan rumus dengan formula berikut:
=SUM(Sheet3!1:1048576)
Kami rasa Anda bisa menuliskan rumus-rumus dan menghasilkan nilai dari rumusnya tanpa perlu lagi dibantu step-by-step-nya karena sudah dijelaskan di atas.
 
Hasilnya bisa Anda lihat sendiri, Excel menjumlahkan seluruh nilai yang ada di Sheet3. Bilangan 1048576 merupakan batas jumlah baris di Excel. 

Asahlah kemampuan Anda menavigasi worksheet caranya adalah pada Sheet4 coba Anda tekan tombol Ctrl + panah bawah untuk menuju sel terakhir Excel lalu tekan Ctrl + panah kanan untuk menempatkan sel di sudut kanan bawah yang paling akhir di worksheet, pointer pun otomatis berada di sel XFD1048576. 

Untuk kembali ke sel A1 tekan Ctrl + Home.

Rumus SUM Excel Menjumlahkan Nilai yang Terakumulasi

Anda tentunya mengenal kata saldo yang artinya selisih atau sisa dari uang yang masuk atau uang yang keluar. Yang akan kita coba praktekkan adalah sebuah contoh sederhana membuat saldo tersebut dimana jumlah pendapatan akan terakumulasi setiap bulan seperti yang dapat dilihat pada Sheet5 file latihan-sum-bukuyudi.xlsx.

Setelah Anda membuka tab Sheet5, ikuti langkah-langkah berikut:
  1. Sorot sel D2:D13.
  2. Masukkan rumus berikut di sel D2: 
    3. =SUM(C$2:C2)
  3. Tekan Ctrl + Enter.

Acuan Sel Absolut

Mengapa harus ada tanda dollar ($) disertakan dalam argumen SUM? 

Kita perhatikan argumen SUM ini terdiri dari sel C$2 dan C2 yang dipisahkan oleh tanda titik dua (:). Sel C$2 ditetapkan sebagai sel absolut dalam Excel karena sel ini berisi nilai urutan pertama dan harus kita kunci barisnya saat disalin (diakumulasikan dengan nilai yang lain) ke bawah dengan cara menambahkan tanda dollar tersebut, sedangkan C2 disebut sel relatif dalam Excel karena sel yang dijadikan nilai urutan terakhir ini pada saat disalin maka akan menyesuaikan output sesuai dengan nilai yang ada di barisnya. 

Formasi Sel Absolut

Untuk Anda catat supaya memudahkan dalam mengingat kegunaan acuan sel absolut, berikut formasi sel absolut beserta artinya:
  1. $C$2: Kolom dan baris yang dikunci (tidak berubah ketika disalin) 
  2. C$2: Baris yang dikunci (tidak berubah ketika disalin)
  3. $C2: Kolom yang dikunci (tidak berubah ketika disalin)

Cara Mengubah Sel Relatif Menjadi Sel Absolut

Anda bisa mengubah sel relatif menjadi sel absolut atau sebaliknya melalui cara berikut:
  1. Coba sorot lagi sel D2:D13.
  2. Letakkan kursor di dekat C$2 (juga bisa di sela-selanya) pada formula bar.
  3. Untuk membuat C$2 menjadi $C$2 maka Anda tekan tombol F4 sebanyak tiga kali hingga menjadi $C$2.
  4. Lalu tekan tombol Ctrl + Enter.

Kelihatannya tampilan kolom D ini masih belum rapi ya, Anda bisa menyembunyikan output saldo yang terakumulasi tersebut pada baris pendapatan yang masih kosong dengan cara menambahkan fungsi IF dengan rumus berikut:
=IF(C2<>"",SUM(C$2:C2),"")

Rumus SUM Excel Menjumlahkan Nilai pada Range yang Ada Errornya

Kenyataannya, fungsi SUM ini tidak mungkin dapat menghasilkan penjumlahan jika diantara barisan sel tersebut terdapat nilai error. Contoh, jika ada salah satu sel saja yang menampilkan error #DIV/0 pada barisan sel yang disorot, maka fungsi SUM juga akan menghasilkan #DIV/0.

Untuk mengatasi permasalahan tersebut, Anda bisa menggunakan fungsi AGGREGATE untuk mengabaikan sel yang error. Seperti pada Sheet6 file latihan-sum-bukuyudi.xlsx terdapat tiga nilai error pada barisan sel B2:D6. Berikut langkah yang dapat Anda ikuti:
  1. Sorot B2:D6. 
  2. Namai barisan sel misalnya 'Angka' pada Name Box.
  3. Letakkan pointer di sel B8.
  4. Masukkan rumus berikut:
    5. =AGGREGATE(9,6,Angka)
Argumen angka 9 artinya nomor urut fungsi SUM, argumen 6 urutan pilihan mengabaikan nilai error. Anda bisa mencoba mengetikkan rumus AGGREGATE ini dengan dipandu menu autocomplete.

Fungsi AGGREGATE ini memiliki kemampuan yang lebih yaitu menjalankan beberapa fungsi pilihan dan variasi pengaturan outputnya.

Rumus SUM Excel Menjumlahkan Data Khusus Nilai-Nilai Tertinggi atau Nilai-Nilai Terendah 

Sebagai contoh misalnya coba Anda jumlahkan lima buah nilai yang tertinggi atau yang terbesar dari suatu daftar seperti pada Sheet7. Terlebih dahulu Anda namai sel B2:B10 pada Name Box dengan nama misalnya 'Jumlah'. 

Nilai yang tertinggi adalah angka 8 dan jumlahnya ada tiga buah, urutan tertinggi keempat ditempati oleh angka 5 yang berjumlah dua buah. Sehingga angka 5 menjadi urutan keempat dan yang kelima. Dengan demikian, angka disusun menurut urutannya 1,2,3,4,5 menjadi 8+8+8+5+5. 

Susunan tetap seperti inilah yang dikenal dengan istilah array constant dalam Excel. Array adalah cara terbaik karena tidak perlu lagi  mengurutkan data. Rumus Array ini digunakan untuk memecahkan permasalahan mencari nilai tertinggi:
=SUM(LARGE(Jumlah,{1,2,3,4,5}))

Untuk mencari nilai terendah, gunakan rumus array berikut:
=SUM(SMALL(Jumlah,{1,2,3,4,5}))

Agar urutan angka-angka tersebut lebih dipersingkat lagi penulisannya, maka rumusnya dapat Anda ubah menjadi:
=SUM(LARGE(Jumlah,ROW(INDIRECT("1:30"))))

Fakta Unik Seputar Fungsi SUM

Jika Anda menemukan fakta unik lainnya seputar fungsi SUM, mohon bagikanlah pengalaman Anda kepada kami dengan cara berkomentar di bawah ya!

Fakta Fungsi SUM #1

Coba Anda bereksperimen misalnya menambahkan nilai logika TRUE atau FALSE ke dalam argumen fungsi SUM seperti ini:
=SUM(FALSE)
yang dihasilkan ternyata angka 0, ini membuktikan bahwa meskipun kelihatannya rumus ini agak konyol tapi faktanya rumus ini berlaku juga dan rupanya tidak menimbulkan error seperti halnya jika dicoba pada fungsi lain misalnya fungsi IF.

Silakan Anda coba saja berkreasi, tambahkan misalnya dengan argumen lainnya contohnya seperti ini:
=SUM(FALSE,SECOND(7),"8",FALSE)
Rumus macam-macam dan aneh yang bisa Anda buat seperti ini sama sekali tidak menimbulkan error. Namun tentu saja tidak semua karakter bisa seenaknya saja dimasukkan ke dalam argumen SUM ini. Ada beberapa jenis argumen yang memungkinkan digunakan dalam fungsi SUM:
  1. Nilai logika (TRUE atau FALSE)
  2. Angka atau bilangan
  3. Sebuah sel atau bisa juga barisan sel yang disorot
  4. Bilangan dalam tanda petik, contoh "123"
  5. Argumen kosong: ,,
  6. Fungsi tertentu lengkap beserta argumennya, contoh: SECOND(7).
Demikian pembahasan tentang Rumus Excel Menjumlahkan Menggunakan Fungsi SUM. Selanjutnya kita akan membahas tahapan berikutnya yaitu menjumlahkan dengan fungsi SUMIF.

Rumus Excel Penjumlahan dengan Kriteria (Rumus SUMIF)

Mungkin diantara Anda ada yang pernah mendengar istilah penjumlahan bersyarat. Dalam penjumlahan bersyarat di Excel, suatu nilai pada barisan sel yang telah memenuhi satu syarat atau lebih maka nilai itulah yang dijumlahkan. 

Pembahasan kita kali ini berfokus pada penggunaan fungsi SUMIF dalam penjumlahan yang harus memenuhi satu kriteria atau persyaratan tertentu. Jika Anda belum mengunduh, Silakan Anda bisa mengunduh file latihan-autosum-bukuyudi.xlsx disini agar materi ini dapat diikuti dengan jelas.

Fungsi SUMIF sintaksnya terdiri dari tiga buah argumen:
  1. range: barisan sel yang berisi nilai penentu yang memenuhi syarat menjumlahkan.
  2. criteria: syarat atau dasar penetapan kriteria tertentu yang harus terpenuhi dalam menjumlahkan.
  3. sum_range: Barisan sel yang berisi sel-sel yang akan dijumlahkan. Namun ini hanya pelengkap, jadi meskipun argumen ini diabaikan, fungsi SUMIF tetap bekerja dengan menggunakan barisan sel yang telah ditetapkan pada argumen pertama yaitu range.

Fungsi SUMIF ini sangat berguna menjadi rumus yang digunakan untuk menjumlahkan dengan satu syarat saja. 

Silakan Anda buka Sheet1 file latihan-autosum-bukuyudi.xlsx, disana terdapat barisan sel contoh catatan piutang dimana kolom F berisi rumus hasil pengurangan tanggal sekarang (Kolom E) dari tanggal janji bayar (Kolom D). Pengurangan ini tentu akan menghasilkan bilangan negatif jika tanggal janji bayar sudah lewat. Anda bisa memberi nama-nama berikut menggunakan Name Box:
  • Sel B4:B12 dengan nama 'Nama'
  • Sel C4:C12 dengan nama 'Besarnya'
  • Sel D4:D12 dengan nama 'Janji'
  • Sel F4:F12 dengan nama 'Selisih'

Rumus SUMIF Excel Menjumlahkan Bilangan Negatif Saja di Suatu Kolom

Pada kolom F terdapat beberapa bilangan negatif yang menunjukkan selisih (hari tersisa) yang telah lewat dari tanggal pada kolom E. Jika Anda ingin menjumlahkan jumlah selisih hari yang telah lewat dari jatuh temponya maka dapat menggunakan rumus sebagai berikut di sel F13 untuk menjumlahkan bilangan negatifnya saja:
=SUMIF(Selisih,"<0")
Argumen SUMIF di atas ditulis begitu sederhana karena mengabaikan argumen ketiga yaitu sum_range. Penulisan argumen SUMIF bahkan bisa dibuat menjadi lebih sederhana lagi yaitu dengan menggunakan sel acuan. Misalnya coba Anda jadikan sel G1 menjadi tempat dituliskannya argumen kedua (criteria) yaitu <0 tanpa tanda petik. Maka penulisan rumusnya di sel F13:
=SUMIF(Selisih,G1)
Dengan begini, akan lebih memudahkan Anda jika ingin mengubah argumen di sel G1 untuk menghasilkan nilai baru misalnya untuk menjumlahkan bilangan positifnya saja maka Anda tinggal mengubahnya menjadi >0.

Rumus SUMIF Excel Menjumlahkan Bilangan pada Suatu Kolom yang Mengacu pada Kolom Lain 

Jika Anda ingin menjumlahkan besar piutang yang lewat dari jatuh temponya saja maka Anda harus menghitung kolom C menurut bilangan yang ada pada kolom F sebagai penentu. Untuk itulah argumen ketiga Anda gunakan sebagai barisan sel output, sehingga rumusnya dapat dituliskan misalnya di sel C15 menjadi:
=SUMIF(Selisih,G1,Besarnya)

Rumus SUMIF Excel Menjumlahkan Bilangan pada Kolom yang Berisi Teks

Anda juga dapat menjumlahkan besar piutang menurut nama yang berhutang. Contohnya Anda ingin mengetahui jumlah total piutang yang harus dibayar Fulan A, maka cara menghitung total di Excel adalah melalui rumus yang dapat dituliskan pada sel C16 menjadi:
=SUMIF(Nama,"Fulan A",Besarnya)
Atau untuk lebih memudahkan, Anda tulis Fulan A tanpa tanda petik di sel B16 dan rumus pada sel C16 menjadi:
=SUMIF(Nama,B16,Besarnya)
Jika Anda ingin menjumlahkan besar piutang semua yang berhutang kecuali misalnya Fulan A, maka pada sel B16 Anda tuliskan <>Fulan A.

Rumus SUMIF Excel Menjumlahkan Bilangan Menurut Perbandingan Tanggal

Kriteria SUMIF tidak hanya berupa bilangan atau teks saja, melainkan dapat berupa suatu tanggal tertentu contohnya dihasilkan melalui fungsi DATE. Sebagai contoh jika Anda ingin menjumlahkan besar piutang yang lewat dari tanggal tertentu misalnya tanggal 1 Februari 2020, maka sel C17 dapat ditulis rumusnya menjadi:
=SUMIF(Janji,">="&DATE(2020,2,1),Besarnya)
Fungsi DATE ini dapat pula Anda tuliskan di sel lain yang terpisah agar Anda lebih mudah mengubahnya misalnya di sel G2, sehingga rumus di atas ditulis menjadi:
=SUMIF(Janji,">="&G2,Besarnya)
Demikian pembahasan tentang Rumus Excel Menjumlahkan Menggunakan Fungsi SUMIF. Mohon maaf atas kekurangan dan kesalahan penulisan pada postingan ini, bantu kami mengkoreksi hasil tulisan kami dengan cara memberikan komentar di bawah ini. Terima kasih banyak.