Cara Menjumlahkan Barisan Sel Bilangan Pada Tiap Kolom Menggunakan Macro VBA Excel

Tip berikut ini menjelaskan cara menambahkan fungsi SUM untuk menghasilkan output penjumlahan bilangan pada setiap kolom. Adapun output tersebut dapat ditempatkan dengan dua cara yakni pada setiap satu sel kosong tepatnya di bawah sel yang berisi nilai terakhir dan di sepanjang baris sejajar dengan satu sel kosong di bawah sel yang berisi nilai paling akhir.

Simak penjelasan beragam teknik menjumlahkan di postingan Cara Menjumlahkan di Excel Lengkap Bagi Pemula (Tahap Demi Tahap)

Menjumlahkan Bilangan Pada Setiap Kolom Di Tiap Satu Sel Kosong Di Bawah Sel Terakhir

Cara ini memungkinkan anda untuk menerapkan rumus pada setiap kolom dengan macam-macam daftar/deretan bilangan seperti yang ditunjukkan pada gambar di atas, dimana rumus ditempatkan pada sel kosong pertama di bawah sel yang berisi bilangan terakhir. Masing-masing output dicetak tebal agar lebih mudah terlihat.

Berikut ini contoh penyusunan kode macronya:

Sub JumlahBarisBaru()
Dim KolomAkhir As Long, KolomX As Long, BarisAkhir As Long
KolomAkhir = _
Cells.Find(What:="*", After:=Range("A1"), _
SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
For KolomX = 1 To KolomAkhir
BarisAkhir = Cells(Rows.Count, KolomX).End(xlUp).Row
With Cells(BarisAkhir + 1, KolomX)
.FormulaR1C1 = "=SUM(R4C:R" & BarisAkhir & "C)"
.Font.Bold = True
End With
Next KolomX
End Sub

Menjumlahkan Bilangan Pada Setiap Kolom Di Sepanjang Baris Sejajar Dengan Satu Sel Kosong Di Bawah Sel Yang Paling Akhir

Berapapun banyaknya kolom pada suatu tabel atau kolom mana saja yang paling banyak daftarnya kode macro berikut ini berfungsi menjumlahkan bilangan tiap kolom tersebut sepanjang baris kosong yang pertama.

Sub JumlahSatuBaris()
Dim Baris As Long
Baris = _
Cells.Find(What:="*", After:=Range("A1"), _
SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row + 1
Dim Kolom As Long
Kolom = _
Cells.Find(What:="*", After:=Range("A1"), _
SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
Range(Cells(Baris, 1), Cells(Baris, Kolom)).Font.Bold = True
Range(Cells(Baris, 1), Cells(Baris, Kolom)).FormulaR1C1 _
= "=SUM(R4C:R" & Baris - 1 & "C)"
End Sub