Dalam tip sebelumnya saya telah menjelaskan Rumus Excel Mengambil Nama Depan Saja yang menggunakan fungsi LEFT dan FIND. Kali ini, formula yang akan digunakan adalah kebalikannya yaitu RIGHT yang menghasilkan nama belakang (huruf/karakter terakhir) dalam suatu rangkaian teks pada sel Excel meskipun mungkin dalam metode ini akan terlihat sedikit rumit, sehingga diharapkan Anda dapat meluangkan sedikit waktu Anda untuk mengikuti tip berikut ini agar dapat mengimplementasikan rumus menurut kegunaannya masing-masing.

Seperti halnya fungsi LEFT, argumen kedua pada fungsi RIGHT yaitu jumlah karakter. Hanya saja jumlah karakter fungsi RIGHT ditetapkan untuk menghapus karakter di depannya sehingga menghasilkan karakter yang terdapat di akhir/belakang, sedangkan jumlah karakter pada fungsi LEFT adalah kebalikannya yaitu menampilkan jumlah karakter di awal/depan.

Langkah-langkah Penyusunan Rumus Mengambil Nama Belakang

Jika dalam suatu sel terdapat teks misalnya 'November Kilo Delta' (yang terdiri dari 19 karakter), untuk menghasilkan kata 'Delta' maka diperlukan jumlah karakter sebanyak 5 sebagai argumen pada fungsi RIGHT. Jumlah tersebut dapat dihasilkan dari selisih keseluruhan karakter. Untuk menghitung jumlah keseluruhan karakter dalam sel (termasuk spasi), Anda dapat menggunakan fungsi LEN, kemudian menyertakan nilai selisih karakter yaitu 19 - 5 = 14, sehingga dapat ditulis menjadi:
=RIGHT(B1,LEN(B1)-14)
Agar menghasilkan output yang lebih efisien, maka selanjutnya nilai selisih (14) dapat Anda susun dengan menggunakan fungsi FIND. Fungsi FIND tentunya tidak akan mungkin digunakan secara terbalik (dari kanan ke kiri) untuk menginformasikan dimana tepatnya posisi karakter spasi sebelum kata/rangkaian karakter terakhir. Namun tidak mustahil jika fungsi tersebut dapat menginformasikan karakter unik lainnya (selain spasi), apabila karakter spasi yang terletak sebelum rangkaian karakter terakhir tersebut diubah menjadi karakter simbol misalnya tanda baca (~, !, @, #, $, dan lain-lain) agar dapat menghasilkan kata contohnya 'November Kilo@Delta'.

Sebagai solusinya Anda dapat menggunakan fungsi SUBSTITUTE yang terdiri dari 4 argumen yaitu sel yang berisi teks atau rangkaian karakter, karakter yang akan diubah, karakter baru dan nomor pilihan perumpamaan posisi karakter baru. Sehingga dapat disusun menjadi:
=SUBSTITUTE(B1," ","@",2)
Kemudian, nomor posisi karakter baru (@) yaitu angka 2 dapat dihasilkan dari selisih antara keseluruhan jumlah karakter beserta spasi (19) dan jumlah karakter tanpa spasi (17). Untuk menghasilkan jumlah karakter tanpa spasi, Anda dapat menyusun rumus:
=LEN(SUBSTITUTE(B1," ",""))
Dengan demikian, didapat susunan rumus untuk menghasilkan angka 2 atau nomor posisi karakter baru (@):
=LEN(B1)-LEN(SUBSTITUTE(B1," ",""))
Setelah itu, rumus digabungkan untuk menghasilkan susunan karakter 'November Kilo@Delta' menjadi sebagai berikut:
=SUBSTITUTE(B1," ","@",LEN(B1)-LEN(SUBSTITUTE(B1," ","")))
Adapun posisi karakter baru (@) kini dapat diketahui dengan menggunakan fungsi FIND, sehingga susunan rumus menghasilkan angka pengurang (14):
=FIND("@",SUBSTITUTE(B1," ","@",LEN(B1)-LEN(SUBSTITUTE(B1," ",""))))

Langkah terakhir, Anda tinggal menggabungkan rumus pengurang tersebut kepada rumus RIGHT dan LEN yang telah disusun sebelumnya di atas, sehingga susunan rumusnya menjadi:
=RIGHT(B1,LEN(B1)-FIND("@",SUBSTITUTE(B1," ","@",LEN(B1)-LEN(SUBSTITUTE(B1," ","")))))