Rumus Excel Menghitung Bilangan Ganjil dan Genap

Untuk menentukan bilangan ganjil maupun genap, Excel telah menyediakan fungsi khusus untuk dapat menginformasikan bilangan tersebut yakni ISODD untuk bilangan ganjil dan ISEVEN untuk bilangan genap. Adapun nilai yang dihasilkan dari fungsi tersebut ialah nilai logika TRUE/FALSE, dimana nilai TRUE menunjukkan nilai yang tepat dari kedua fungsi yang digunakan tersebut di atas.

Nilai-nilai logika yang telah dihasilkan selanjutnya dapat dihitung dengan menggunakan fungsi COUNTIF dengan argumen TRUE, seperti yang ditunjukkan pada gambar di bawah ini. Sel B2:B14 menghasilkan nilai logika menggunakan fungsi ISODD dan Sel C2:C14 menggunakan fungsi ISEVEN. Hasil perhitungan terdapat pada sel B15 dengan rumus:
=COUNTIF(B2:B14,TRUE) 
dan sel C15 dengan rumus:
=COUNTIF(C2:C14,TRUE)


Tip berikut ini akan membahas mengenai metode perhitungan bilangan ganjil dan genap dalam bentuk yang lebih sederhana dan efisien dibandingkan dengan metode perhitungan COUNTIF di atas sehingga dapat memungkinkan anda untuk menghasilkan perhitungan dari sebuah susunan rumus array tanpa harus membuat baris bantu atau kolom bantu berisi fungsi ISODD atau ISEVEN.

Rumus array merupakan teknik dalam Excel untuk menyusun rumus-rumus tersendiri yang dapat dioperasikan melalui sekumpulan argumen-argumen yang tersusun dari baris maupun kolom sel. Pada prinsipnya, Excel akan mencatat suatu barisan sel atau kolom sel seperti yang ditunjukkan pada gambar di bawah ini.


Excel akan mengubah barisan sel A2:A14 yang disorot pada sel E2 menjadi:
={71;96;42;11;39;4;70;68;88;81;57;76;91} 
setelah anda menekan tombol F9 pada keyboard.

Untuk membuktikan fungsi ISODD atau ISEVEN agar layak menghasilkan output array, maka anda dapat melakukan pengujian seperti pada sel E3 dimana rumus: =ISODD(A2:A14) menghasilkan nilai error yakni #VALUE!. Dengan demikian, fungsi ISODD maupun ISEVEN ini tidak dapat digunakan dalam rumus array.

Namun apabila rumus berisi operasi bilangan tertentu seperti contohnya pada sel E4: =A2:A14*2=8, maka Excel menghasilkan output array berupa nilai-nilai logika:
={FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE} 
setelah anda menekan tombol F9.

Dengan demikian, barisan sel maupun kolom sel hanya dapat berfungsi sebagai argumen pada fungsi-fungsi Excel tertentu. Untuk menentukan nilai-nilai manakah yang merupakan bilangan ganjil maupun genap dapat dilakukan dengan cara mengetahui nilai sisa setelah nilai tersebut dibagi dengan angka 2. Nilai ganjil tentunya akan menghasilkan nilai 1 dan nilai genap menghasilkan nilai 0. Adapun fungsi Excel yang dapat digunakan ialah fungsi MOD.

Anda dapat menyusun rumus untuk menentukan bilangan ganjil dengan menambahkan operasi bilangan '=1' atau '=0' untuk bilangan genap, dengan penulisan:
=MOD(A2:A14,2)=1
Seperti yang ditunjukkan pada gambar di bawah ini, Sel C2 menghasilkan output array setelah tombol F9 ditekan:
={TRUE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;TRUE} 
sehingga fungsi MOD merupakan fungsi yang tepat sebagai alternatif fungsi ISODD dan ISEVEN.


Output array selanjutnya dapat dihitung menggunakan fungsi SUMPRODUCT dengan argumen yang tidak lazim seperti yang telah dibahas pada posting sebelumnya Rumus Excel Menghitung Nilai Soal Pilihan Ganda. Berikut ini susunan rumus yang digunakan dalam contoh worksheet seperti pada gambar di bawah ini:
Sel D1: =SUMPRODUCT(--(MOD(A2:A14,2)=1))
Sel D2: =SUMPRODUCT(--(MOD(A2:A14,2)=0))

Rumus ini dapat pula digunakan untuk menghitung sekumpulan tanggal ganjil maupun genap sebagaimana contoh pada gambar di bawah ini.


Sel A2:A14 berisi tanggal dengan format sel Number menggunakan Custom: [$-421]dddd, d mmmm yyyy;@ agar menghasilkan format tanggal bahasa Indonesia. Fungsi DAY digunakan untuk mengambil bilangan tanggal saja kemudian dijadikan sebagai argumen dalam fungsi MOD dengan susunan rumus berikut:
Sel D1: =SUMPRODUCT(--(MOD(DAY(A2:A14),2)=1))
Sel D2: =SUMPRODUCT(--(MOD(DAY(A2:A14),2)=0))