Tip berikut ini akan mempertunjukkan bagaimana cara menampilkan pembaruan pada fitur comment dalam Excel supaya dapat menampilkan kepingan data unik dalam susunan yang telah diurutkan dari suatu daftar di kolom tertentu yang berisi data ganda di dalamnya.

Jadi pada saat data unik yang terbaru ditambahkan ke dalam daftar tersebut, maka fitur comment akan segera memperbarui data secara real-time.

Seperti yang dipertunjukkan dalam gambar di atas saat tanggal dan barang terbaru ditambahkan ke dalam daftar, seperti yang terjadi pada sel A20 dan B20, maka comment pada sel B1 langsung diperbarui untuk menampilkan nama barang terbaru yang telah diurutkan sesuai dengan abjad.

Silakan Anda ikuti langkah demi langkah berikut ini untuk menyusun kode macro:

1. Contoh macro ini menggunakan prosedur event Worksheet_Change, maka dari itu kode ini dibuat pada module worksheet, langkah pertama adalah siapkan worksheet yang berisi data ganda, Anda bisa menyalin data contoh seperti pada gambar, kemudian klik kanan tab sheet-nya. 

2. Pilih View Code.

3. Pada kotak pilihan Object (General) di atas module worksheet klik tanda panah di ujungnya.

4. Pilih Worksheet.

5. Pada kotak pilihan Procedure (Declarations) di atas module worksheet, klik tanda panah di ujungnya.

6. Pilih event Change.

7. Ketik kode berikut tepat dibawah Private Sub Worksheet_Change:

Private Sub Worksheet_Change(ByVal Target As Range)

8. Batasi event untuk memantau perubahan hanya pada kolom B saja:

If Target.Column <> 2 Then Exit Sub

9. Siapkan pengaturan aplikasi Excel:

With Application
.ScreenUpdating = False
.DisplayAlerts = False
.EnableEvents = False

10. Tetapkan variabel-variabel berikut:

Dim kb As Long, s As Range, ct As String

11. Tentukan kolom bantu yang mana kolom terakhir ditambah angka 3 untuk membuat daftar barang unik kemudian mengurutkannya menurut abjad:

kb = _
Cells.Find(What:="*", After:=Range("B1"), _
SearchOrder:=xlByColumns, _
SearchDirection:=xlPrevious).Column + 3

12. Catat daftar nama barang unik pada kolom bantu:

Range("B1:B" & Cells(Rows.Count, 1).End(xlUp).Row).AdvancedFilter _
Action:=xlFilterCopy, CopyToRange:=Cells(1, kb), Unique:=True

13. Urutkan namanya berdasarkan abjad mulai dari A ke Z (Ascending):

Cells(1, kb).Sort _
Key1:=Cells(2, kb), _
Order1:=xlAscending, _
Header:=xlYes

14. Pada titik ini, Anda membuat tulisan pada comment, yang mana terdiri dari setiap nama barang unik dalam daftar menurun. 

ct = ""
For Each s In Cells(1, kb).CurrentRegion

15. Bypass sel judul pada baris pertama worksheet:

If s.Row <> 1 Then _

16. Pisahkan setiap namanya dengan garis baru menggunakan aksara ascii yaitu Char(10):

ct = ct & Chr(10) & s.Value
Next s
ct = "Daftar barang unik:" & Chr(10) & ct

17. Sel B1 adalah sel yang menampilkan comment:

With Range("B1")
If Not .Comment Is Nothing Then .Comment.Delete
.AddComment
With .Comment
.Visible = False
.Text Text:=ct
.Shape.TextFrame.AutoSize = True
End With
End With

18. Hapus kolom bantu yang memuat daftar unik yang telah diwakili dalam comment:

Columns(kb).Clear
.EnableEvents = True
.DisplayAlerts = True
.ScreenUpdating = True
End With

19. Susunan kode lengkapnya adalah sebagai berikut:

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column <> 2 Then Exit Sub
With Application
.ScreenUpdating = False
.DisplayAlerts = False
.EnableEvents = False
Dim kb As Long, s As Range, ct As String
kb = _
Cells.Find(What:="*", After:=Range("B1"), _
SearchOrder:=xlByColumns, _
SearchDirection:=xlPrevious).Column + 3
Range("B1:B" & Cells(Rows.Count, 1).End(xlUp).Row).AdvancedFilter _
Action:=xlFilterCopy, CopyToRange:=Cells(1, kb), Unique:=True
Cells(1, kb).Sort _
Key1:=Cells(2, kb), _
Order1:=xlAscending, _
Header:=xlYes
ct = ""
For Each s In Cells(1, kb).CurrentRegion
If s.Row <> 1 Then _
ct = ct & Chr(10) & s.Value
Next s
ct = "Daftar barang unik:" & Chr(10) & ct
With Range("B1")
If Not .Comment Is Nothing Then .Comment.Delete
.AddComment
With .Comment
.Visible = False
.Text Text:=ct
.Shape.TextFrame.AutoSize = True
End With
End With
Columns(kb).Clear
.EnableEvents = True
.DisplayAlerts = True
.ScreenUpdating = True
End With
End Sub

20. Buka kembali worksheet dengan menekan Alt+Q

21. Masukkan tanggal dan nama barang terbaru lalu amati perubahan pada comment di sel B1.

Itulah penjelasan tentang cara menampilkan pembaruan pada fitur comment dalam Excel supaya dapat menampilkan data unik dalam susunan yang telah diurutkan dari suatu daftar pada kolom tertentu yang berisi data ganda.

Selamat mencoba dan semoga postingan ini bermanfaat.