Pada umumnya telah diketahui bahwa dalam satu tahun itu terdiri dari 52 minggu, namun pada saat banyaknya minggu-minggu tersebut ditentukan ke dalam Excel menggunakan fungsi WEEKNUM, seringkali menghasilkan output yang keliru mengenai hari atau tanggal acuan pada awal tahun yang akan ditetapkan sebagai minggu pertama.

Fungsi WEEKNUM terdiri dari 2 buah argumen yakni Serial_num atau urutan bilangan dalam Excel yang direpresentasikan sebagai tanggal dan Return_type atau angka yang mewakili nama hari yang dijadikan sebagai awal dari minggu pertama, dimana angka 1 mewakili hari Minggu dan angka 2 mewakili hari Senin. Fungsi Excel ini hanya dapat menetapkan tanggal 1 Januari sebagai minggu pertama dalam satu tahun.

Tip berikut ini akan menjelaskan cara menghitung banyaknya minggu-minggu dalam satu tahun menurut tanggal pada suatu sel dengan ketentuan bahwa minggu pertama di awal tahun terhitung mulai dari hari Senin di bulan Januari dan akhir tahun jatuh pada hari Minggu di bulan Januari. Hal ini dikarenakan tanggal 1 Januari pada setiap tahun dapat juga bertepatan pada waktu di selain hari Senin.


Seperti yang terlihat pada gambar di atas yang menunjukkan contoh worksheet sederhana dimana tanggal 1 Januari 2016 bertepatan dengan hari Jumat. Adapun format tanggal pada sel B1 menggunakan Custom Number: [$-421]dddd, d mmmm yyyy;@

Ketiga output pada sel B2:B4 menggunakan rumus yang berbeda, dimana rumus ke 1 dihasilkan dari fungsi WEEKNUM dengan menetapkan angka 1 (mewakili hari Minggu) pada argumen keduanya, sedangkan rumus ke 2 argumen kedua berisi angka 2 (mewakili hari Senin), dan rumus ke 3 menggunakan susunan rumus yang lebih sesuai untuk menghasilkan output yang dapat mendefinisikan bahwa hari Jumat tersebut ditetapkan bukan minggu ke 1 meskipun bertepatan dengan tanggal 1 Januari 2016. Rumus ke 3 ini akan menetapkan 4 Januari atau hari Senin sebagai minggu ke 1 dalam tahun 2016.

Rumus pada sel B2 dapat disusun menjadi:
="Minggu ke "&WEEKNUM(B1,1)&", Tahun "&YEAR(B1)
Dan sel B3:
="Minggu ke "&WEEKNUM(B1,2)&", Tahun "&YEAR(B1)

Langkah Pertama 

Untuk menyusun rumus pada sel B4 dapat dilakukan dengan mengetahui tahun yang dapat menentukan apakah tahun pada tanggal di sel B1 merupakan awal atau akhir tahun jika minggu pertama awal tahun tersebut terhitung mulai dari hari Senin. Hal ini dapat diketahui dengan cara mengidentifikasi terlebih dahulu bilangan hari pada tanggal di sel B1 (dimana hari ke 1 yakni Senin). Adapun rumusnya adalah:
=WEEKDAY(B1+6)
Rumus tersebut akan menghasilkan bilangan 5 yang menunjukkan bahwa hari Jumat adalah hari ke 5, output berikutnya yang akan dihasilkan adalah tanggal tepatnya 1 hari sebelum tanggal di sel B1. Hal ini dapat dilakukan dengan cara menambahkan sel B1 dan bilangan -1 agar menghasilkan output 'Kamis, 31 Desember 2015'. Sehingga bilangan 5 yang dihasilkan oleh rumus di atas dijadikan pengurang bilangan positif yakni +4. Dengan demikian rumus disusun menjadi:
=B1+4-WEEKDAY(B1+6)
Dari susunan rumus tersebut, tahun yang dicari kini dapat ditampilkan menggunakan fungsi YEAR:
=YEAR(B1+4-WEEKDAY(B1+6))

Langkah Kedua

Berikutnya menetapkan tanggal 3 Januari dengan tahun berdasarkan pada rumus dalam langkah pertama di atas, sehingga rumusnya adalah:
=DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,3)
Rumus ini selanjutnya digunakan untuk mengidentifikasi bilangan hari yang dapat dituliskan dengan menambahkan fungsi WEEKDAY, maka rumusnya menjadi:
=WEEKDAY(DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,3))
Rumus ini adalah rumus (1).

Langkah Ketiga

Tanggal yang ditetapkan berikutnya yakni 5 Januari dengan tahun berdasarkan pada rumus dalam langkah pertama di atas, dengan susunan rumusnya adalah:
=DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,5)
Rumus ini adalah rumus (2).

Langkah Terakhir

Rumus (1) dan (2) selanjutnya dijumlahkan dan kemudian dijadikan pengurang terhadap tanggal pada sel B1, hasil pengurangan tersebut seluruhnya dibagi dengan jumlah hari dalam seminggu, dengan demikian susunan rumusnya sebagai berikut:
=(B1-DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,5)+WEEKDAY(DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,3)))/7
Hilangkan bilangan desimal pada hasil rumus dengan menggunakan fungsi INT lalu tambahkan dengan angka 1 sehingga rumus menjadi:
=INT((B1-DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,5)+WEEKDAY(DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,3)))/7)+1
Hasil akhir dari rumus dalam sel B4 dapat disesuaikan menurut kebutuhan untuk menghasilkan output contohnya seperti 'Minggu ke 53, Tahun 2015' dengan penulisan sebagai berikut:
="Minggu ke "&INT((B1-DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,5)+WEEKDAY(DATE(YEAR(B1+4-WEEKDAY(B1+6)),1,3)))/7)+1&", Tahun "&YEAR(B1+4-WEEKDAY(B1+6))